Drive Serial Number

GET CONFIGURATION Command - Operation Code $46
DRIVE SERIAL FEATURE - Feature Number $0108

Im Kapitel Feature wurde die Feature List ermittelt. In Kapitel 5.3.40 der Multi-Media Commands 6 ist das optionale Feature Drive Serial Number beschrieben. Damt lässt sich die Seriennummer des Laufwerkes ermitteln. Die meisten virtuellen Laufwerke besitzen keine.

Der GET CONFIGURATION Command Descriptor Block:

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches zuerst ausgegeben werden soll, an. Abhängig vom Request Type kann es auch das einzige sein. Das DRIVE SERIAL FEATURE hat die Featurenummer $0108.

Byte 7 und 8: Länge der Antwortstruktur. Die Länge muss so groß gewählt werden, dass die Antwort hineinpasst. Der Featureheader hat eine Länge von acht Byte. Die Featurebeschreibung besteht aus einem vier Byte langen Header gefolgt von einer maximal 256 Byte langen Seriennummer. Somit ergibt sich eine maximale Länge von 268 Byte ($010C).

Byte 9: Control - ?

Antwortstruktur

Die Struktur variiert in seiner Länge. Wenn das Feature nicht unterstützt wird, ist sie acht Byte lang. Zuerst der Feature Header:

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, was bei virtuellen Laufwerken die Regel sein dürfte. Sonst gilt, das noch vier Byte Header und vier Byte Feature Drive Serial Beschreibung bis zur Serial Number folgen und der Wert mehr als acht betragen muss.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend folgt die DRIVE SERIAL FEATURE Beschreibung, falls dieses Feature unterstützt wird:

Feature Code - Muss der selbe wie im CDB sein. Hier war das DRIVE SERIAL Feature $0108 ausgewählt.

Version - Die Versionsnummer muss 0000b sein.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert gibt die Länge der folgenden Serial Number an. Es muss ein Vielfaches von vier sein.

Serial Number - Die Nummer besteht aus ASCII-Zeichen aus dem Wertebereich von $20 bis $7E. Ungenutzte Bytes werden mit maximal drei Leerzeichen ($20) aufgefüllt.

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_DRIVE_SERIAL_NUMBER = $0108;
 
type
  TGET_CONFIGURATION_DRIVE_SERIAL_NUMBER = record
    Header : Array[0..7] of Byte;
    Data   : Array[0..$010C] of Byte;
  end;
  PGET_CONFIGURATION_DRIVE_SERIAL_NUMBER = ^TGET_CONFIGURATION_DRIVE_SERIAL_NUMBER;
 
type
  TFeatureDriveSerial = record
    FeatureCode  : Word;
    Version      : Byte;
    Persistent   : Boolean;
    Current      : Boolean;
    AddLength    : Byte;
    SerialNumber : String;
  end;

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigDriveSerialNumber(aDevice: THandle): Boolean;
{*******************************************************************************
*  Drive Serial Number Feature
}
var
  GET_CONFIGURATION_CDB    : TGET_CONFIGURATION_CDB;
  pConfigDriveSerialNumber : PGET_CONFIGURATION_DRIVE_SERIAL_NUMBER;
  aCDB                     : Array of Byte;
  DataLength               : Cardinal;
  n                        : Integer;
begin
  Result := False;
  {
  *  Drive Serial Number Feature initialisieren.
  }
  FillChar(FDrive[FActive].DriveSerialNumber,
           SizeOf(TFeatureDriveSerialNumber), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_DRIVE_SERIAL_NUMBER;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_DRIVE_SERIAL_NUMBER);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigDriveSerialNumber, SizeOf(TGET_CONFIGURATION_DRIVE_SERIAL_NUMBER));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigDriveSerialNumber,
                                  SizeOf(TGET_CONFIGURATION_DRIVE_SERIAL_NUMBER))
  then begin
    DataLength := pConfigDriveSerialNumber.Header[0] shl 24 or
                  pConfigDriveSerialNumber.Header[1] shl 16 or
                  pConfigDriveSerialNumber.Header[2] shl  8 or
                  pConfigDriveSerialNumber.Header[3];
    {
    *  Wenn das DRIVE SERIAL Feature existiert.
    }
    if DataLength > 4 then
    with FDrive[FActive].DriveSerialNumber
    do begin
      FeatureCode   := pConfigDriveSerialNumber.Data[0] shl 8 or
                       pConfigDriveSerialNumber.Data[1];
      Version       := pConfigDriveSerialNumber.Data[2] and $3C shr 2;
      Persistent    := pConfigDriveSerialNumber.Data[2] and $02 > 0;
      Current       := pConfigDriveSerialNumber.Data[2] and $01 > 0;
      AddLength     := pConfigDriveSerialNumber.Data[3];
      if AddLength > 0 then
      for n := 1 to AddLength
      do SerialNumber := SerialNumber + Chr(pConfigDriveSerialNumber.Data[3 + n]);
      {
      *  Ergebnis
      }
      Result := FeatureCode = FEATURE_DRIVE_SERIAL_NUMBER;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

Drive Serial Number (podDriveSerialNumber.7z - 258 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo