Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - Content Scramble System

Content Scramble System

GET CONFIGURATION Command - Operation Code $46
DVD CSS FEATURE - Feature Number $0106

Im Kapitel Feature wurde die Feature List ermittelt. In Kapitel 5.3.38 der Multi-Media Commands 6 ist das Feature DVD CSS FEATURE beschrieben. Damt lässt sich ermitteln, ob das Content Scramble System unterstützt wird. Dieses System verschlüsselt den Videostream. Ohne Entschlüsselung erhält man ein grünes Bild.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $0106
3
4Reserviert
5
6
7Allocation Length = $0010
8
9Control

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches ausgegeben werden soll, an. Das DVD CSS FEATURE hat die Featurenummer $0106.

Byte 7 und 8: Länge der Antwortstruktur. Die Beschreibung des DVD CSS FEATURE hat eine Länge von acht Byte. Mit den acht Byte des Feature Headers ergeben sich 16 Byte.

Byte 9: Control - ?

Antwortstruktur

Zuerst der Feature Header:

 76543210
0Data Length
1
2
3
4Reserviert
5
6Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend folgt die DVD CSS FEATURE Beschreibung, falls dieses Feature unterstützt wird:

 76543210
0Feature Code = $0106
1
2ReserviertVersion = 0000bPersistentCurrent
3Additional Length = $04
4Reserviert
5
6
7CSS Version

Feature Code - Muss der selbe wie im CDB sein. Das DVD CSS Feature mit der Featurenummer $0106.

Version - Es gibt nur die Versionsnummer 0000b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss $04 betragen.

CSS Version - Gibt die CSS Version an. Der Wert muss eins sein.

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_DVD_CSS = $0106;
 
type
  TGET_CONFIGURATION_DVD_CSS = record
    Header : array[0..7] of Byte;
    Data   : array[0..7] of Byte;
  end;
  PGET_CONFIGURATION_DVD_CSS = ^TGET_CONFIGURATION_DVD_CSS;
 
type
  TFeatureDVDCSS = record
    FeatureCode  : Word;
    Version      : Byte;
    Persistent   : Boolean;
    Current      : Boolean;
    AddLength    : Byte;
    CSSVersion   : Byte;
  end;

Ausführung und Auswertung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigDVDCSS(aDevice: THandle): Boolean;
{*******************************************************************************
*  DVD CSS Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigDVDCSS         : PGET_CONFIGURATION_DVD_CSS;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  DVD CSS Feature initialisieren.
  }
  FillChar(FDrive[FActive].DVDCSS, SizeOf(TFeatureDVDCSS), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_DVD_CSS;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_DVD_CSS);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigDVDCSS, SizeOf(TGET_CONFIGURATION_DVD_CSS));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigDVDCSS,
                                  SizeOf(TGET_CONFIGURATION_DVD_CSS))
  then begin
    DataLength := pConfigDVDCSS.Header[0] shl 24 or
                  pConfigDVDCSS.Header[1] shl 16 or
                  pConfigDVDCSS.Header[2] shl  8 or
                  pConfigDVDCSS.Header[3];
    {
    *  Wenn das Feature existiert.
    }
    if DataLength > 4 then
    with FDrive[FActive].DVDCSS
    do begin
      FeatureCode := pConfigDVDCSS.Data[0] shl 8 or pConfigDVDCSS.Data[1];
      Version     := pConfigDVDCSS.Data[2] and $3C shr 2;
      Persistent  := pConfigDVDCSS.Data[2] and $02 > 0;
      Current     := pConfigDVDCSS.Data[2] and $01 > 0;
      AddLength   := pConfigDVDCSS.Data[3];
      {
      *  Wenn Daten existieren.
      }
      if AddLength > 0
      then CSSVersion := pConfigDVDCSS.Data[7];
      {
      *  Ergebnis
      }
      Result := FDrive[FActive].DVDCSS.FeatureCode = FEATURE_DVD_CSS;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

DVD CSS (podDVDCSS.7z - 257 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.

$0051 - HD DVD WRITE > $0106 - CSS > $0108 - DRIVE SERIAL NUMBER