Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - HD DVD WRITE

HD DVD WRITE

GET CONFIGURATION Command - Operation Code $46
HD DVD WRITE FEATURE - Feature Number $0051

Im Kapitel Feature wurde die Feature List ermittelt. Mit dem HD DVD WRITE FEATURE (Feature Number $0051 - MMC 6 Kapitel 5.3.35) erhält man Auskunft darüber, ob das Laufwerk HD DVD-R und HD DVD-RAM schreiben kann.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $0051
3
4Reserviert
5
6
7Allocation Length = $0010
8
9Control

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3: Starting Feature Number - Gibt die Nummer des auszugebenden Feature an. Das HD DVD WRITE FEATURE hat die Featurenummer $0051.

Byte 7 und 8: Länge der Antwortstruktur. Die Beschreibung des HD DVD WRITE FEATURE ist acht Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 16 ($0010).

Byte 9: Control - ?

Antwortstruktur

Die Struktur beginnend mit dem Feature Header:

 76543210
0Data Length
1
2
3
4Reserviert
5
6/td>Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

HD DVD WRITE FEATURE Beschreibung:

 76543210
0Feature Code = $0051
1
2ReserviertVersion = 0000bPersistentCurrent
3Additional Length = $04
4ReserviertHD DVD-R
5Reserviert
6ReserviertHD DVD-RAM
7Reserviert

Feature Code - Muss der selbe wie im CDB sein. Hier war das HD DVD READ Feature $0050 ausgewählt.

Version - Es gibt nur die Versionsnummer 0000b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss vier betragen.

HD DVD-R - Gibt an, ob das Laufwerk HD DVD-R Medien schreiben kann.

HD DVD-RAM - Gibt an, ob das Laufwerk HD DVD-RAM Medien schreiben kann.

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_HDDVD_WRITE = $0051;
 
type
  TGET_CONFIGURATION_HDDVD_WRITE = record
    Header : array[0..7] of Byte;
    Data   : array[0..7] of Byte;
  end;
 
type
  TFeatureHDDVDWrite = record
    FeatureCode : Word;
    Version     : Byte;
    Persistent  : Boolean;
    Current     : Boolean;
    AddLength   : Byte;
    R           : Boolean;
    RAM         : Boolean;
  end;

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigHDDVDWrite(aDevice: THandle): Boolean;
{*******************************************************************************
*  HD DVD WRITE Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigHDDVDWrite     : PGET_CONFIGURATION_HDDVD_WRITE;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  HD DVD WRITE Feature initialisieren.
  }
  FillChar(FDrive[FActive].HDDVDWrite, SizeOf(TFeatureHDDVDWrite), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_HDDVD_WRITE;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_HDDVD_WRITE);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, CDB10GENERIC_LENGTH);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigHDDVDWrite, SizeOf(TGET_CONFIGURATION_HDDVD_WRITE));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigHDDVDWrite,
                                  SizeOf(TGET_CONFIGURATION_HDDVD_WRITE))
  then begin
    DataLength := pConfigHDDVDWrite.Header[0] shl 24 or
                  pConfigHDDVDWrite.Header[1] shl 16 or
                  pConfigHDDVDWrite.Header[2] shl  8 or
                  pConfigHDDVDWrite.Header[3];
    {
    *  Wenn das HD DVD READ Feature existiert.
    }
    if DataLength > 4 then
    with FDrive[FActive].HDDVDWrite
    do begin
      FeatureCode := pConfigHDDVDWrite.Data[0] shl 8 or pConfigHDDVDWrite.Data[1];
      Version     := pConfigHDDVDWrite.Data[2] and $3C shr 2;
      Persistent  := pConfigHDDVDWrite.Data[2] and $02 > 0;
      Current     := pConfigHDDVDWrite.Data[2] and $01 > 0;
      AddLength   := pConfigHDDVDWrite.Data[3];
      {
      *  Wenn Daten existieren.
      }
      if AddLength > 0
      then begin
        R   := pConfigHDDVDWrite.Data[4] and $01 > 0;
        RAM := pConfigHDDVDWrite.Data[6] and $01 > 0;
      end;
      {
      *  Ergebnis
      }
      Result := FeatureCode = FEATURE_HDDVD_WRITE;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

HD DVD WRITE (podHDDVDWrite.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.

$0050 - HD DVD READ > $0051 - HD DVD WRITE > $0106 - DVD CSS