Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - BD WRITE

BD WRITE

GET CONFIGURATION Command - Operation Code $46
BD WRITE FEATURE - Feature Number $0041

Im Kapitel Feature wurde die Feature List ermittelt. Mit dem BD WRITE FEATURE (Feature Number $0041) aus Multimedia Commands 6 Kapitel 5.3.30) erhält man Auskunft darüber, ob das Laufwerk BD schreiben kann.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $0041
3
4Reserviert
5
6
7Allocation Length = $0020
8
9Control

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3: Starting Feature Number - Die Nummer des abzurufenden Feature. Das BD WRITE FEATURE hat die Featurenummer $0041.

Byte 7 und 8: Länge der Antwortstruktur. Die Länge muss so gewählt werden, dass die Antwort hineinpasst. Die Beschreibung des BD WRITE FEATURE ist 24 Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 32 ($20).

Byte 9: Control - ?

Antwortstruktur

Die Struktur sieht dann beginnend mit dem Feature Header so aus:

 76543210
0Data Length
1
2
3
4Reserviert
5
6Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst 28.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

BD WRITE FEATURE Beschreibung:

 76543210
0Feature Code = $0041
1
2>ReserviertVersion = 0000bPersistentCurrent
3Additional Length = $14
4ReserviertSVNR
5Reserviert
6
7
8Veraltet
9VeraltetRE2Veraltet
10Veraltet
11
12
13
14
15
16
17VeraltetRVeraltet
18Veraltet
19
20
21
22
23

Feature Code - Muss der selbe wie im CDB sein. Hier war das BD WRITE Feature $0041 ausgewählt.

Version - Das Feature gibt es seit MMC-4. In MMC-6 wurde die Beschreibung geändert. Die Versionsnummer wurde jedoch nicht geändert und ist weiter 0000b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss 20 betragen.

SVNR (Supports Verify Not Required) - Gibt an, ob das WRITE(12) Command VNR unterstützt.

RE2 - Gibt an, ob das Laufwerk BD-RE Version 2 Medien lesen kann.

R - Gibt an, ob das Laufwerk BD-R Version 1 Medien lesen kann.

Bei den veralteten Daten handelt es sich Class Bitmaps für BD-RE.

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_BD_WRITE = $0041;
 
type
  TGET_CONFIGURATION_BD_WRITE = record
    Header : Array[0..7] of Byte;
    Data   : Array[0..23] of Byte;
  end;
  PGET_CONFIGURATION_BD_WRITE = ^TGET_CONFIGURATION_BD_WRITE;
 
type
  TFeatureBDWrite = record
    FeatureCode : Word;
    Version     : Byte;
    Persistent  : Boolean;
    Current     : Boolean;
    AddLength   : Byte;
    SVNR        : Boolean;
    RE2         : Boolean;
    R           : Boolean;
  end;

Ausführung und Auswertung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigBDWrite(aDevice: THandle): Boolean;
{*******************************************************************************
*  BD Write Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigBDWrite        : PGET_CONFIGURATION_BD_WRITE;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  BD WRITE Feature initialisieren.
  }
  FillChar(FDrive[FActive].BDWrite, SizeOf(TFeatureBDWrite), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_BD_WRITE;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_BD_WRITE);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigBDWrite, SizeOf(TGET_CONFIGURATION_BD_WRITE));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigBDWrite,
                                  SizeOf(TGET_CONFIGURATION_BD_WRITE))
  then begin
    DataLength := pConfigBDWrite.Header[0] shl 24 or
                  pConfigBDWrite.Header[1] shl 16 or
                  pConfigBDWrite.Header[2] shl  8 or
                  pConfigBDWrite.Header[3];
    {
    *  Wenn das BD WRITE Feature existiert.
    }
    if DataLength > 4
    then begin
      FDrive[FActive].BDWrite.FeatureCode := pConfigBDWrite.Data[0] shl 8 or
                                             pConfigBDWrite.Data[1];
      FDrive[FActive].BDWrite.Version     := pConfigBDWrite.Data[2] and $3C shr 2;
      FDrive[FActive].BDWrite.Persistent  := pConfigBDWrite.Data[2] and $02 > 0;
      FDrive[FActive].BDWrite.Current     := pConfigBDWrite.Data[2] and $01 > 0;
      FDrive[FActive].BDWrite.AddLength   := pConfigBDWrite.Data[3];
      {
      *  Wenn Daten existieren.
      }
      if FDrive[FActive].BDWrite.AddLength > 0
      then begin
        FDrive[FActive].BDWrite.SVNR := pConfigBDWrite.Data[4] and $01 > 0;
        FDrive[FActive].BDWrite.RE2  := pConfigBDWrite.Data[9] and $04 > 0;
        FDrive[FActive].BDWrite.R    := pConfigBDWrite.Data[17] and $02 > 0;
      end;
      {
      *  Ergebnis
      }
      Result := FDrive[FActive].BDWrite.FeatureCode = FEATURE_BD_WRITE;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

BD WRITE (podBDWrite.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.

$0040 - BD READ> $0041 - BD WRITE > $0050 - HD DVD READ