Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - BD READ

BD READ

GET CONFIGURATION Command - Operation Code $46
BD READ FEATURE - Feature Number $0040

Im Kapitel Feature wurde die Feature List ermittelt. Mit dem BD READ FEATURE (Feature Number $0040) aus Multimedia Commands 6 Kapitel 5.3.29 erhält man Auskunft darüber, ob das Laufwerk BD lesen kann.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $0040
3
4Reserviert
5
6
7Allocation Length = $28
8
9Control

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3: Starting Feature Number - Gibt die Nummer des auszugebenden Feature an. Das BD READ FEATURE hat die Featurenummer $0040.

Byte 7 und 8: Länge der Antwortstruktur. Die Länge muss so gewählt werden, dass die Antwort hineinpasst. Die Beschreibung des BD READ FEATURE ist 32 Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 40 ($28).

Byte 9: Control - ?

Antwortstruktur

Die Struktur sieht dann beginnend mit dem Feature Header so aus:

 76543210
0Data Length
1
2
3
4Reserviert
5
6Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst 36.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

BD READ FEATURE Beschreibung:

 76543210
0Feature Code = $0040
1
2ReserviertVersion = 0001bPersistentCurrent
3Additional Length = $1C
4ReservedBCA
5Reserved
6
7
8Veraltet
9VeraltetRE2RE1Veraltet
10Veraltet
11
12
13
14
15
16
17VeraltetRVeraltet
18Veraltet
19
20
21
22
23
24
25VeraltetROMVeraltet
26Veraltet
27
28
29
30
31

Feature Code - Muss der selbe wie im CDB sein. Hier war das BD READ Feature $0040 ausgewählt.

Version - Die Versionsnummer muss 0001b sein.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - gibt an, ob die Eigenschaft zur Zeit aktiv ist. Das heißt, ob ein entsprechendes Medium eingelegt ist.

Additional Length - Der Wert muss 28 betragen.

BCA - Gibt an, ob das Laufwerk BCA Daten über das READ DISC STRUCTURE command mit dem Media Type $1 und dem Format Code $03 lesen kann.

RE2 - Gibt an, ob das Laufwerk BD-RE Version 2 Medien lesen kann.

RE1 - Gibt an, ob das Laufwerk BD-RE Version 1 Medien lesen kann.

R - Gibt an, ob das Laufwerk BD-R Version 1 Medien lesen kann.

ROM - Gibt an, ob das Laufwerk BD-ROM Version 1 Medien lesen kann.

Bei den veralteten Daten handelte es sich in der Version $00 um Class Bitmaps für BD-RE und BD-R.

Deklaration

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_BD_READ = $0040;
 
type
  TGET_CONFIGURATION_BD_READ = record
    Header : array[0..7] of Byte;
    Data   : array[0..31] of Byte;
  end;
  PGET_CONFIGURATION_BD_READ = ^TGET_CONFIGURATION_BD_READ;
 
type
  TFeatureBDRead = record
    FeatureCode : Word;
    Version     : Byte;
    Persistent  : Boolean;
    Current     : Boolean;
    AddLength   : Byte;
    BCA         : Boolean;
    RE2         : Boolean;
    RE1         : Boolean;
    R           : Boolean;
    ROM         : Boolean;
  end;

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigBDRead(aDevice: THandle): Boolean;
{*******************************************************************************
*  BD Read Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigBDRead         : PGET_CONFIGURATION_BD_READ;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  BD READ Feature initialisieren.
  }
  FillChar(FDrive[FActive].BDRead, SizeOf(TFeatureBDRead), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
  GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
  GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_BD_READ;
  GET_CONFIGURATION_CDB.AllocationLength      := SizeOf(TGET_CONFIGURATION_BD_READ);
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigBDRead, SizeOf(TGET_CONFIGURATION_BD_READ));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigBDRead,
                                  SizeOf(TGET_CONFIGURATION_BD_READ))
  then begin
    DataLength := pConfigBDRead.Header[0] shl 24 or
                  pConfigBDRead.Header[1] shl 16 or
                  pConfigBDRead.Header[2] shl  8 or
                  pConfigBDRead.Header[3];
    {
    *  Wenn das BD READ Feature existiert.
    }
    if DataLength > 4
    then begin
      FDrive[FActive].BDRead.FeatureCode := pConfigBDRead.Data[0] shl 8 or
                                            pConfigBDRead.Data[1];
      FDrive[FActive].BDRead.Version     := pConfigBDRead.Data[2] and $3C shr 2;
      FDrive[FActive].BDRead.Persistent  := pConfigBDRead.Data[2] and $02 > 0;
      FDrive[FActive].BDRead.Current     := pConfigBDRead.Data[2] and $01 > 0;
      FDrive[FActive].BDRead.AddLength   := pConfigBDRead.Data[3];
      {
      *  Wenn Daten existieren.
      }
      if FDrive[FActive].BDRead.AddLength > 0
      then begin
        FDrive[FActive].BDRead.BCA := pConfigBDRead.Data[4] and $01 > 0;
        FDrive[FActive].BDRead.RE2 := pConfigBDRead.Data[9] and $04 > 0;
        FDrive[FActive].BDRead.RE1 := pConfigBDRead.Data[9] and $02 > 0;
        FDrive[FActive].BDRead.R   := pConfigBDRead.Data[17] and $02 > 0;
        FDrive[FActive].BDRead.ROM := pConfigBDRead.Data[25] and $02 > 0;
      end;
      {
      *  Ergebnis
      }
      Result := FDrive[FActive].BDRead.FeatureCode = FEATURE_BD_READ;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

BD READ (podBDRead.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.

$003B - DVD+R DUAL LAYER> $0040 - BD READ > $0041 - BD WRITE