Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - DVD READ

Random Writable

GET CONFIGURATION Command - Operation Code $46
RANDOM WRITABLE FEATURE - Feature Number $0020

Im Kapitel Feature wurde die Feature List ermittelt. Die Feature werden im Kapitel 5 beschrieben. So in Kapitel 5.3.10 das RANDOM WRITABLE Feature. Dieses gibt an, ob das Laufwerk Daten in zufälliger Folge von logischen Blöcken, welche durch logische Blockadressen angegeben werden, schreiben kann.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0/td>Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $0020
3
4Reserviert
5
6
7Allocation Length = $0018
8
9Control

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3 Starting Feature Number - $0020: Gibt die Nummer des Feature, welches ausgegeben werden soll, an.

Byte 7 und 8 Allocation Length - $0018: Länge der Antwortstruktur. Die Antwort besteht aus dem Feature Header (acht Byte) und der RANDOM WRITABLE Feature Beschreibung (16 Byte), also 24 Byte.

Byte 9: Control - ?

Antwortstruktur

Der Feature Header:

 76543210
0Data Length
1
2
3
4Reserviert
5
6Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Beschreibungen an. Der Wert ist ein Vielfaches von vier.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Die Feature Beschreibung:

 76543210
0Feature Code = $0020
1
2ReserviertVersion = 0001bPersistentCurrent
3Additional Length = $0C
4Last Logical Block Address
5
6
7
8Logical Block Size
9>
10
11
12Blocking
13
14ReserviertPP
15Reserviert

Feature Code - Gibt die Nummer des abgerufenen Features an. Wird es unterstützt folgt die Beschreibung.

Version - Die Versionsnummer ist von unterstützten Standard und dem Feature abhängig.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Wird das Feature unterstützt ist der Wert zwölf, anderenfalls null.

Last Logical Block Address - Die logische Blockadresse des letzten adressierbaren Blockes auf dem Medium.

Logical Block Size - Die Größe eines logischen Blockes in Bytes. Dies ist der selbe Wert wie man ihn mit dem READ CAPACITY command erhält.

Blocking - Die Anzahl der logischen Blöcke, welche auf einmal eingelesen werden können. Der Wert ist vom eingelegten Medium abhängig. Für CD $01, für DVD $10 und BD $20.

PP (Page Present) - Gibt an, ob die Read/Write Error Recovery mode page vorhanden ist.

Wenn das RANDOM WRITABLE Feature unterstützt wird, werden auch diese Commands und Mode Pages unterstützt:

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_RANDOM_WRITABLE  = $0020;
 
type
  TGET_CONFIGURATION_RANDOM_WRITABLE = record
    Header : Array[0..$07] of Byte;
    Data   : Array[0..$0F] of Byte;
  end;
  PGET_CONFIGURATION_RANDOM_WRITABLE = ^TGET_CONFIGURATION_RANDOM_WRITABLE;
 
  TFeatureRandomWritable = record
    FeatureCode      : Word;
    Version          : Byte;
    Persistent       : Boolean;
    Current          : Boolean;
    AdditionalLength : Byte;
    LastLogBlockAddr : Cardinal;
    LogicalBlockSize : Cardinal;
    Blocking         : Word;
    PP               : Boolean;
  end;

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigRandomWritable(aDevice: THandle): Boolean;
{*******************************************************************************
*  Random Writable Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigRandomWritable : PGET_CONFIGURATION_RANDOM_WRITABLE;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  Random Writable Feature initialisieren.
  }
  FillChar(FDrive[FActive].RandomWritable, SizeOf(TFeatureRandomWritable), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_RANDOM_WRITABLE;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_RANDOM_WRITABLE);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigRandomWritable, SizeOf(TGET_CONFIGURATION_RANDOM_WRITABLE));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigRandomWritable,
                                    SizeOf(TGET_CONFIGURATION_RANDOM_WRITABLE))
  then begin
    {
    *  Wenn der Aufruf erfolgreich war...
    }
    DataLength := pConfigRandomWritable.Header[0] shl 24 or
                  pConfigRandomWritable.Header[1] shl 16 or
                  pConfigRandomWritable.Header[2] shl  8 or
                  pConfigRandomWritable.Header[3];
    {
    *  Wenn das Feature existiert.
    }
    if DataLength >= 4 then
    with FDrive[FActive].RandomWritable
    do begin
      FeatureCode      := pConfigRandomWritable.Data[0] shl 8 or
                          pConfigRandomWritable.Data[1];
      Version          := pConfigRandomWritable.Data[2] and $3C shr 2;
      Persistent       := pConfigRandomWritable.Data[2] and $02 > 0;
      Current          := pConfigRandomWritable.Data[2] and $01 > 0;
      AdditionalLength := pConfigRandomWritable.Data[3];
       {
      *  Wenn Daten existieren.
      }
      if AdditionalLength > 0
      then begin
        LastLogicalBlockAddress := pConfigRandomWritable.Data[4] shl 24 or
                                   pConfigRandomWritable.Data[5] shl 16 or
                                   pConfigRandomWritable.Data[6] shl 8 or
                                   pConfigRandomWritable.Data[7];
        LogicalBlockSize        := pConfigRandomWritable.Data[8] shl 24 or
                                   pConfigRandomWritable.Data[9] shl 16 or
                                   pConfigRandomWritable.Data[10] shl 8 or
                                   pConfigRandomWritable.Data[11];
        Blocking                := pConfigRandomWritable.Data[12] shl 8 or
                                   pConfigRandomWritable.Data[13];
        PagePresent             := pConfigRandomWritable.Data[14] and $01 > 0;
      end;
      {
      *  Ergebnis
      }
      Result := FeatureCode = FEATURE_RANDOM_WRITABLE;
    end;
  end;
end;

Demo, welche diese Funktion nutzt:

Random Writable (podRandomWritable.7z - 253 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.
18.03.2012Fehler: Beschriftung des Tabs.

$001F DVD READ > $0020 - RANDOM WRITABLE > $002A - DVD+RW READ