Home | Kontakt | Sitemap

Start

Über mich

Kontakt

Sitemap

Lizenz

Anleitungen

DVD, miniDVD

SVCD

Audio, Audio-CD (CD-DA)

AVI

Software

Von Freunden und Bekannten

Eigene Programme

Programmierung

Delphi

Lazarus

Delphi/Lazarus

Projekte

MPEG-1/2 Video

Optische Laufwerke

Audio-CD (CDDA)

Raspberry Pi Dashcam

Verschiedenes

MPEG 2 Schnitt

Project X

VCD Easy

Hardlinks

Windows

Links

Software

Projekte | Optische Laufwerke - Merkmale (Feature) - CD READ

CD READ

GET CONFIGURATION Command - Operation Code $46
CD READ FEATURE - Feature Number $001E

Im Kapitel Feature wurde die Feature List ermittelt. Das CD Read Feature ist in den Multimedia Commands 6 in Kapitel 5.3.8 beschrieben. Es gibt an, ob Digital Audio Play, C2 Flags und CD Text unterstützt werden.

Der GET CONFIGURATION Command Descriptor Block:

 76543210
0Operation Code = $46
1ReserviertRT = 10b
2Starting Feature Number = $001E
3
4Reserviert
5
6
7Allocation Length = $10
8
9Control

Die Werte:

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

WertBeschreibung
00bDas Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10bDas Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11bReserviert

Byte 2 und 3: Starting Feature Number - $001E Gibt an, dass das CD READ FEATURE abgerufen werden soll.

Byte 7 und 8: Länge der Antwortstruktur - $10 Die Länge muss so groß gewählt werden, dass die erwartete Antwort hineinpasst. Die Beschreibung des CD READ FEATURE ist acht Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 16.

Byte 9: Control - ?

Antwortstruktur

Der Header wie auch bei den anderen Features:

 76543210
0Data Length
1
2
3
4Reserviert
5
6Current Profile
7

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend die CD READ FEATURE Beschreibung:

 76543210
0Feature Code = $001E
1
2ReserviertVersion = 0010bPersistentCurrent
3Additional Length = $04
4DAPReservedC2 FlagsCD-Text
5Reserved
6
7

Feature Code - Muss der selbe wie im CDB sein. Hier war das CD READ Feature $001E ausgewählt.

Version - Die Versionsnummer muss 0010b sein.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss vier betragen.

DAP - Gibt an, ob die READ CD und READ CD MSF Commands Digital Audio Play unterstützen.

C2 Flags - Gibt an, ob C2 Error Pointer unterstützt werden.

CD-Text - Gibt an, ob CD-Text unterstützt wird. Das heißt, es wird der Format Code $5 beim READ TOC/PMA/ATIP Command unterstützt.

Deklaration

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_CD_READ = $001E;
 
type
  TGET_CONFIGURATION_CD_READ = record
    Header : Array[0..7] of Byte;
    Data   : Array[0..7] of Byte;
  end;
 
type
  TFeatureCDRead = record
  FeatureCode : Word;
  Version     : Byte;
  Persistent  : Boolean;
  Current     : Boolean;
  AddLength   : Byte;
  DAP         : Boolean;
  C2Flags     : Boolean;
  CDText      : Boolean;
end;

Ausführung

Nach der Aufruf des Commands wird die Antwortstruktur ausgewertet. Beispiel einer Funktion:

function TOptDrives.ReadConfigCDRead(aDevice: THandle): Boolean;
{*******************************************************************************
*  CD Read Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigCDRead         : PGET_CONFIGURATION_CD_READ;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  CD Read initialisieren.
  }
  FillChar(FDrive[FActive].CDRead, SizeOf(TFeatureCDRead), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
  GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
  GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_CD_READ;
  GET_CONFIGURATION_CDB.AllocationLength      := SizeOf(TGET_CONFIGURATION_CD_READ);
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigCDRead, SizeOf(TGET_CONFIGURATION_CD_READ));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigCDRead,
                                    SizeOf(TGET_CONFIGURATION_CD_READ))
  then begin
    DataLength := pConfigCDRead.Header[0] shl 24 or
                  pConfigCDRead.Header[1] shl 16 or
                  pConfigCDRead.Header[2] shl  8 or
                  pConfigCDRead.Header[3];
    {
    *  Wenn der Abruf erfolgreich war...
    }
    if DataLength > 4 then
    with FDrive[FActive].CDRead
    do begin
      FeatureCode := pConfigCDRead.Data[0] shl 8 or pConfigCDRead.Data[1];
      Version     := pConfigCDRead.Data[2] and $3C shr 2;
      Persistent  := pConfigCDRead.Data[2] and $02 > 0;
      Current     := pConfigCDRead.Data[2] and $01 > 0;
      AddLength   := pConfigCDRead.Data[3];
      {
      *  Wenn Daten vorhanden sind.
      }
      if AddLength > 0
      then begin
        DAP     := pConfigCDRead.Data[4] and $80 > 0;
        C2Flags := pConfigCDRead.Data[4] and $02 > 0;
        CDText  := pConfigCDRead.Data[4] and $01 > 0;
      end;
      {
      *  Ergebnis
      }
      Result := FeatureCode = FEATURE_CD_READ);
    end;
  end;
  FreeMem(pConfigCDRead);
end;

Demo, welche diese Funktion nutzt:

CD READ (podCDRead.7z - 252 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.

$0010 - RANDOM READABLE > $001E CD READ > $001F - DVD READ