Projekte > Optische Laufwerke > Merkmale

Video Content Protection System

GET CONFIGURATION Command - Operation Code $46
VCPS FEATURE - Feature Number $0110

Das Kapitel 5,3.51 der Multi-Media Commands 6 (r02a) beschreibt das VCPS Feature, welches Eigenschaften dieses Rechteverwaltungssystems enthält. In den Multimedia Commands 6 ist dieses Feature nicht mehr enthalten.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $0110
3
4 Reserviert
5
6
7 Allocation Length = $0010
8
9 Control

 

Die zu setzenden Werte:

Byte 0: Operation Code - $46

Byte 1: RT - Request Type 01b:

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches ausgegeben werden soll, an. Das VCPS FEATURE hat die Featurenummer $0110.

Byte 7 und 8: Länge der Antwortstruktur. Die Beschreibung des VCPS FEATURE hat eine Länge von acht Byte. Mit den acht Byte des Feature Headers ergeben sich 16 Byte.

Byte 9: Control - ?

 

Antwortstruktur

Zuerst der Feature Header:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend folgt die VCPS FEATURE Beschreibung, falls dieses Feature unterstützt wird:

  7 6 5 4 3 2 1 0
0 Feature Code = $0110
1
2 Reserviert Version = 0000b Persistent Current
3 Additional Length = $04
4 Reserviert
5
6
7

 

Feature Code - Muss der selbe wie im CDB sein. Das VCPS Feature mit der Featurenummer $0110.

Version - Es gibt nur die Versionsnummer 0000b.

Persistent, Current - Gibt an, ob die Eigenschaft geändert werden kann und ob sie zur Zeit aktiv ist.

Additional Length - Der Wert muss $04 betragen.

 

Deklaration

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_VCPS = $0110;
 
  type
    TGET_CONFIGURATION_VCPS = record
      Header : array[0..7] of Byte;
      Data   : array[0..7] of Byte;
    end;
    PGET_CONFIGURATION_VCPS = ^TGET_CONFIGURATION_VCPS;
 
  type
    TFeatureVCPS = record
      FeatureCode  : Word;
      Version      : Byte;
      Persistent   : Boolean;
      Current      : Boolean;
      AddLength    : Byte;
    end;
        

 

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  function TOptDrives.ReadConfigVCPS(aDevice: THandle): Boolean;
  {*******************************************************************************
  *  VCPS Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigVCPS           : PGET_CONFIGURATION_VCPS;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  VCPS Feature Description initialisieren.
    }
    FillChar(FDrive[FActive].VCPS, SizeOf(TFeatureVCPS), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
    GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
    GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_VCPS;
    GET_CONFIGURATION_CDB.AllocationLength      := SizeOf(TGET_CONFIGURATION_VCPS);
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigVCPS, SizeOf(TGET_CONFIGURATION_VCPS));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigVCPS,
                                    SizeOf(TGET_CONFIGURATION_VCPS))
    then begin
      DataLength := pConfigVCPS.Header[0] shl 24 or
                    pConfigVCPS.Header[1] shl 16 or
                    pConfigVCPS.Header[2] shl  8 or
                    pConfigVCPS.Header[3];
      {
      *  Wenn das Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].VCPS
      do begin
        FeatureCode := pConfigVCPS.Data[0] shl 8 or pConfigVCPS.Data[1];
        Version     := pConfigVCPS.Data[2] and $3C shr 2;
        Persistent  := pConfigVCPS.Data[2] and $02 > 0;
        Current     := pConfigVCPS.Data[2] and $01 > 0;
        AddLength   := pConfigVCPS.Data[3];
        {
        *  Ergebnis
        }
        Result := FeatureCode = FEATURE_VCPS;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

VCPS (podVCPS.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.