Projekte > Optische Laufwerke > Merkmale

Advanced Access Content System

GET CONFIGURATION Command - Operation Code $46
AACS FEATURE - Feature Number $010D

Mit dem AACS Feature aus Kapitel 5.3.44 der Multimedia Commands 6 lässt sich ermitteln, ob dieses System zum digitalen Rechtemanagement unterstützt wird.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $010D
3
4 Reserviert
5
6
7 Allocation Length = $0010
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches ausgegeben werden soll, an. Das AACS FEATURE hat die Featurenummer $010D.

Byte 7 und 8: Länge der Antwortstruktur. Die Beschreibung des AACS FEATURE hat eine Länge von acht Byte. Mit den acht Byte des Feature Headers ergeben sich 16 Byte ($0010).

Byte 9: Control - ?

 

Antwortstruktur

Zuerst der Feature Header:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend folgt die AACS FEATURE Beschreibung, falls dieses Feature unterstützt wird:

  7 6 5 4 3 2 1 0
0 Feature Code = $010D
1
2 Reserviert Version = 0010b Persistent Current
3 Additional Length = $04
4 Reserviert RDC RMC WBE BEC BNG
5 Block Count for Binding Nonce
6 Reserviert Number of AGIDs
7 AACS Version

 

Feature Code - Muss der selbe wie im CDB sein. Das AACS Feature mit der Featurenummer $010D.

Version - Ist in der MMC-6 0010b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss $04 betragen.

RDC - Gibt an, ob das Laufwerk für AACS lizensiert ist.

RMC - Gibt an, ob das READ DISC STRUCTURE Command mit Formatcode $86 unterstützt wird.

WBE, BEC - Betreffen die Unterstützung der Busverschlüsselung.

BNG - Gibt an, ob Binding Nonce Generating unterstützt wird.

Block Count for Binding Nonce - Gibt an, wieviele Mediablöcke zum Speichern der Bindung Nonce benötigt werden.

Number of AGIDs - Gibt an, wieviele AGIDs maximal gleichzeitig unterstützt werden.

AACS Version - Gibt die AACS Version an. Der Wert ist null oder eins.

 

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_AACS = $010D;
 
  type
    TGET_CONFIGURATION_AACS = record
      Header : Array[0..7] of Byte;
      Data   : Array[0..7] of Byte;
    end;
    PGET_CONFIGURATION_AACS = ^TGET_CONFIGURATION_AACS;
 
  type
    TFeatureAACS = record
      FeatureCode : Word;
      Version     : Byte;
      Persistent  : Boolean;
      Current     : Boolean;
      AddLength   : Byte;
      RDC         : Boolean;
      RMC         : Boolean;
      WBE         : Boolean;
      BEC         : Boolean;
      BNG         : Boolean;
      BlockCount  : Byte;
      nAGIDS      : Byte;
      AACSVersion : Byte;
    end;
        

 

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  function TOptDrives.ReadConfigAACS(aDevice: THandle): Boolean;
  {*******************************************************************************
  *  AACS Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigAACS           : PGET_CONFIGURATION_AACS;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  AACS Feature initialisieren.
    }
    FillChar(FDrive[FActive].AACS, SizeOf(TFeatureAACS), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
    GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
    GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_AACS;
    GET_CONFIGURATION_CDB.AllocationLength      := SizeOf(TGET_CONFIGURATION_AACS);
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigAACS, SizeOf(TGET_CONFIGURATION_AACS));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigAACS,
                                    SizeOf(TGET_CONFIGURATION_AACS))
    then begin
      DataLength := pConfigAACS.Header[0] shl 24 or
                    pConfigAACS.Header[1] shl 16 or
                    pConfigAACS.Header[2] shl  8 or
                    pConfigAACS.Header[3];
      {
      *  Wenn das Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].AACS
      do begin
        FeatureCode := pConfigAACS.Data[0] shl 8 or pConfigAACS.Data[1];
        Version     := pConfigAACS.Data[2] and $3C shr 2;
        Persistent  := pConfigAACS.Data[2] and $02 > 0;
        Current     := pConfigAACS.Data[2] and $01 > 0;
        AddLength   := pConfigAACS.Data[3];
        {
        *  Wenn Daten existieren.
        }
        if AddLength > 0
        then begin
          RDC         := pConfigAACS.Data[4] and $10 > 0;
          RMC         := pConfigAACS.Data[4] and $08 > 0;
          WBE         := pConfigAACS.Data[4] and $04 > 0;
          BEC         := pConfigAACS.Data[4] and $02 > 0;
          BNG         := pConfigAACS.Data[4] and $01 > 0;
          BlockCount  := pConfigAACS.Data[5];
          nAGIDS      := pConfigAACS.Data[6] and $0F;
          AACSVersion := pConfigAACS.Data[7];
        end;
        {
        *  Ergebnis
        }
        Result := FeatureCode = FEATURE_AACS;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

AACS (podAACS.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.