Projekte > Optische Laufwerke > Merkmale

Firmware Information

GET CONFIGURATION Command - Operation Code $46
FIRMWARE INFORMATION FEATURE - Feature Number $010C

In Kapitel 5.3.43 der Multimadia Command 6 ist das optimale FIRMWARE INFORMATION Feature bechrieben. Mit diesem kann man bei Laufwerken, welche mindestens die Multimedia Commands 4 unterstützen, den Zeitpunkt erfahren wann die gegenwärtige Firmware des Laufwerkes entwickelt wurde. Es wird das Datum und die Uhrzeit zur Verfügung gestellt. Sie werden in GMT angegeben. Wenn diese Eigenschaft unterstützt wird, kann der Status nicht geändert werden und die Eigenschaft ist immer aktiv.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $010C
3
4 Reserviert
5
6
7 Allocation Length = $001C
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 

Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches zuerst ausgegeben werden soll, an. Abhängig vom Request Type kann es auch das einzige sein. Das FIRMWARE INFORMATION FEATURE hat die Featurenummer $010C.

Byte 7 und 8: Länge der Antwortstruktur - $001C. Die Länge muss so gewählt werden, dass die Antwort aufgenommen werden kann. Die Beschreibung des FIRMWARE INFORMATION FEATURE hat eine Länge von 20 Byte. Mit den acht Byte des Feature Headers ergeben sich 28 Byte.

Byte 9: Control - ?

 

Antwortstruktur

Die Struktur hat eine Länge von 28 Byte. Wenn das Feature nicht unterstützt wird, erhält man nur den acht Byte langen Feature Header:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst 24.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Anschließend folgt die FIRMWARE INFORMATION FEATURE Beschreibung, falls dieses Feature unterstützt wird:

  7 6 5 4 3 2 1 0
0 Feature Code = $010C
1
2 Reserviert Version = 0000b Persistent Current
3 Additional Length = $10
4 Century = Jahrhundert
5
6 Year = Jahr
7
8 Month = Monat
9
10 Day = Tag
11
12 Hour = Stunde
13
14 Minute = Minute
15
16 Second = Sekunde
17
18 Reserviert
19

 

Feature Code - Muss der selbe wie im CDB sein. Hier war das FIRMWARE INFORMATION Feature mit der Nummer $010C ausgewählt.

Version - Die Versionsnummer muss 0000b sein.

Persistent und Current - Müssen, wenn das Feature unterstützt wird gesetzt sein.

Additional Length - Der Wert muss $10 betragen.

Century, Year, Month, Day, Hour, Minute und Second sind numerische Werte als ASCII-Zeichen. Deshalb werden diese Felder in der Antwortstruktur als Character deklariert.

 

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_FIRMWARE_INFORMATION = $010C;
 
  type
    TFIRMWARE_INFORMATION = record
      Data     : Array[0..3] of Byte;
      Century  : Array[0..1] of AnsiChar;
      Year     : Array[0..1] of AnsiChar;
      Month    : Array[0..1] of AnsiChar;
      Day      : Array[0..1] of AnsiChar;
      Hour     : Array[0..1] of AnsiChar;
      Minute   : Array[0..1] of AnsiChar;
      Second   : Array[0..1] of AnsiChar;
      Reserved : Array[0..1] of AnsiChar;
    end;
 
    TGET_CONFIGURATION_FIRMWARE_INFORMATION = record
      Header       : Array[0..7] of Byte;
      FirmwareInfo : TFIRMWARE_INFORMATION;
    end;
 
  type
    TFeatureFirmwareInformation = record
      FeatureCode  : Word;
      Version      : Byte;
      Persistent   : Boolean;
      Current      : Boolean;
      AddLength    : Byte;
      CenturyYear  : AnsiString;
      Month        : AnsiString;
      Day          : AnsiString;
      Hour         : AnsiString;
      Minute       : AnsiString;
      Second       : AnsiString;
    end;
        

 

Ausführung und Auswertung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  function TOptDrives.ReadConfigFirmwareInformation(aDevice: THandle): Boolean;
  {******************************************************************8*************
  *  Firmware Information Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigFirmwareInfo   : PGET_CONFIGURATION_FIRMWARE_INFORMATION;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  Firmware Information Feature initialisieren.
    }
    FillChar(FDrive[FActive].FirmwareInfo, SizeOf(TFeatureFirmwareInformation), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    with GET_CONFIGURATION_CDB#
    do begin
      OperationCode         := SCSIOP_GET_CONFIGURATION;
      RequestType           := RT_Identified;
      StartingFeatureNumber := FEATURE_FIRMWARE_INFORMATION;
      AllocationLength      := SizeOf(TGET_CONFIGURATION_FIRMWARE_INFORMATION);
    end;
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigFirmwareInfo, SizeOf(TGET_CONFIGURATION_FIRMWARE_INFORMATION));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigFirmwareInfo,
                                    SizeOf(TGET_CONFIGURATION_FIRMWARE_INFORMATION))
    then begin
      DataLength := pConfigFirmwareInfo.Header[0] shl 24 or
                    pConfigFirmwareInfo.Header[1] shl 16 or
                    pConfigFirmwareInfo.Header[2] shl  8 or
                    pConfigFirmwareInfo.Header[3];
      {
      *  Wenn das FIRMWARE INFORMATION Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].FirmwareInfo
      do begin
        FeatureCode   := pConfigFirmwareInfo.FirmwareInfo.Data[0] shl 8 or
                         pConfigFirmwareInfo.FirmwareInfo.Data[1];
        Version       := pConfigFirmwareInfo.FirmwareInfo.Data[2] and $3C shr 2;
        Persistent    := pConfigFirmwareInfo.FirmwareInfo.Data[2] and $02 > 0;
        Current       := pConfigFirmwareInfo.FirmwareInfo.Data[2] and $01 > 0;
        AddLength     := pConfigFirmwareInfo.FirmwareInfo.Data[3];
        {
        *  Wenn ein Datum angegeben ist.
        }
        if AddLength > 0
        then begin
          Century := pConfigFirmwareInfo.FirmwareInfo.Century;
          Year    := pConfigFirmwareInfo.FirmwareInfo.Year;
          Month   := pConfigFirmwareInfo.FirmwareInfo.Month;
          Day     := pConfigFirmwareInfo.FirmwareInfo.Day;
          Hour    := pConfigFirmwareInfo.FirmwareInfo.Hour;
          Minute  := pConfigFirmwareInfo.FirmwareInfo.Minute;
          Second  := pConfigFirmwareInfo.FirmwareInfo.Second;
        end;
        {
        *  Ergebnis
        }
        Result := FeatureCode = FEATURE_FIRMWARE_INFORMATION;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

Firmware Information (podFirmwareInfo.7z - 259 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.