Projekte > Optische Laufwerke > Merkmale

Content Protection for Recordable Media

GET CONFIGURATION Command - Operation Code $46
DVD CPRM FEATURE - Feature Number $010B

DVD CPRM FEATURE (Kapitel 5.3.42) lässt sich ermitteln, ob das Laufwerk die Authentifizierung und das Schlüsselmanagement für beschreibbare Medien unterstützt.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $010B
3
4 Reserviert
5
6
7 Allocation Length = $0010
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Gibt die Nummer des Feature, welches ausgegeben werden soll, an. Das DVD CPRM FEATURE hat die Featurenummer $010B.

Byte 7 und 8: Länge der Antwortstruktur. Die Beschreibung des DVD CPRM FEATURE hat eine Länge von acht Byte. Mit den acht Byte des Feature Headers ergeben sich 16 Byte.

Byte 9: Control - ?

 

Antwortstruktur

Der Featureheader

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Es folgt die DVD CPRM FEATURE Beschreibung, falls dieses Feature unterstützt wird:

  7 6 5 4 3 2 1 0
0 Feature Code = $010B
1
2 Reserviert Version = 0000b Persistent Current
3 Additional Length = $04
4 Reserviert
5
6
7 CPRM Version

 

Feature Code - Muss der selbe wie im CDB sein. Das DVD CPRM Feature hat die Featurenummer $010B.

Version - Es gibt nur die Versionsnummer 0000b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss $04 betragen.

CPRM Version - Gibt die CPRM Version an. Der Wert muss eins sein.

 

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

const
  FEATURE_DVD_CPRM = $010B;
 
type
  TGET_CONFIGURATION_DVD_CPRM = record
    Header : Array[0..7] of Byte;
    Data   : Array[0..7] of Byte;
  end;
  PGET_CONFIGURATION_DVD_CPRM = ^TGET_CONFIGURATION_DVD_CPRM;
 
type
  TFeatureDVDCPRM = record
    FeatureCode  : Word;
    Version      : Byte;
    Persistent   : Boolean;
    Current      : Boolean;
    AddLength    : Byte;
    CPRMVersion  : Byte;
  end;

 

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

function TOptDrives.ReadConfigDVDCPRM(aDevice: THandle): Boolean;
{*******************************************************************************
*  DVD CPRM Feature
}
var
  GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
  pConfigDVDCPRM        : PGET_CONFIGURATION_DVD_CPRM;
  aCDB                  : Array of Byte;
  DataLength            : Cardinal;
begin
  Result := False;
  {
  *  DVD CPRM Feature initialisieren.
  }
  FillChar(FDrive[FActive].DVDCPRM, SizeOf(TFeatureDVDCPRM), $00);
  {
  *  Den Command Descriptor Block füllen.
  }
  ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
  with GET_CONFIGURATION_CDB
  do begin
    OperationCode         := SCSIOP_GET_CONFIGURATION;
    RequestType           := RT_Identified;
    StartingFeatureNumber := FEATURE_DVD_CPRM;
    AllocationLength      := SizeOf(TGET_CONFIGURATION_DVD_CPRM);
  end;
  {
  *  Den Command Descriptor Block übertragen.
  }
  SetLength(aCDB, 10);
  aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
  aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
  aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
  aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
  aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
  {
  *  Befehl ausführen
  }
  GetMem(pConfigDVDCPRM, SizeOf(TGET_CONFIGURATION_DVD_CPRM));
  if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigDVDCPRM,
                                  SizeOf(TGET_CONFIGURATION_DVD_CPRM))
  then begin
    DataLength := pConfigDVDCPRM.Header[0] shl 24 or
                  pConfigDVDCPRM.Header[1] shl 16 or
                  pConfigDVDCPRM.Header[2] shl  8 or
                  pConfigDVDCPRM.Header[3];
    {
    *  Wenn das Feature existiert.
    }
    if DataLength > 4 then
    with FDrive[FActive].DVDCPRM
    do begin
      FeatureCode := pConfigDVDCPRM.Data[0] shl 8 or pConfigDVDCPRM.Data[1];
      Version     := pConfigDVDCPRM.Data[2] and $3C shr 2;
      Persistent  := pConfigDVDCPRM.Data[2] and $02 > 0;
      Current     := pConfigDVDCPRM.Data[2] and $01 > 0;
      AddLength   := pConfigDVDCPRM.Data[3];
      {
      *  Wenn Daten existieren.
      }
      if AddLength > 0
      then CPRMVersion := pConfigDVDCPRM.Data[7];
      {
      *  Ergebnis
      }
      Result := FeatureCode = FEATURE_DVD_CPRM;
    end;
  end;
end;

 

Demo, welche diese Funktion nutzt:

DVD CPRM (podDVDCPRM.7z - 258 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

02.06.2013Kleine Überarbeitung und neuer Name.