Projekte > Optische Laufwerke > Merkmale

HD DVD READ

GET CONFIGURATION Command - Operation Code $46
HD DVD READ FEATURE - Feature Number $0050

Im Kapitel Feature wurde die Feature List ermittelt. Mit dem HD DVD READ FEATURE (Feature Number $0050 - MMC 6 Kapitel 5.3.34) erhält man Auskunft darüber, ob das Laufwerk HD DVD-R und HD DVD-RAM lesen kann.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $0050
3
4 Reserviert
5
6
7 Allocation Length = $0010
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Die Nummer des gewünschten Feature. Das HD DVD READ FEATURE hat die Featurenummer $0050.

Byte 7 und 8: Länge der Antwortstruktur - $0010. Die Beschreibung des HD DVD READ FEATURE ist acht Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 16 ($0010).

Byte 9: Control - ?

 

Antwortstruktur

Die Struktur sieht beginnend mit dem Feature Header so aus:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

HD DVD READ FEATURE Beschreibung:

  7 6 5 4 3 2 1 0
0 Feature Code = $0050
1
2 Reserviert Version = 0000b Persistent Current
3 Additional Length = $04
4 Reserviert HD DVD-R
5 Reserviert
6 Reserviert HD DVD-RAM
7 Reserviert

 

Feature Code - Muss der selbe wie im CDB sein. Hier war das HD DVD READ Feature $0050 ausgewählt.

Version - Es gibt nur die Versionsnummer 0000b.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss vier betragen.

HD DVD-R - Gibt an, ob das Laufwerk HD DVD-R Medien lesen kann.

HD DVD-RAM - Gibt an, ob das Laufwerk HD DVD-RAM Medien lesen kann.

 

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_HDDVD_READ = $0050;
 
  type
    TGET_CONFIGURATION_HDDVD_READ = record
      Header : Array[0..7] of Byte;
      Data   : Array[0..7] of Byte;
    end;
    PGET_CONFIGURATION_HDDVD_READ = ^TGET_CONFIGURATION_HDDVD_READ;
 
  type
    TFeatureHDDVDRead = record
      FeatureCode : Word;
      Version     : Byte;
      Persistent  : Boolean;
      Current     : Boolean;
      AddLength   : Byte;
      R           : Boolean;
      RAM         : Boolean;
    end;
        

 

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  function TOptDrives.ReadConfigHDDVDRead(aDevice: THandle): Boolean;
  {*******************************************************************************
  *  HD DVD READ Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigHDDVDRead      : PGET_CONFIGURATION_HDDVD_READ;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  HD DVD READ Feature initialisieren.
    }
    FillChar(FDrive[FActive].HDDVDRead, SizeOf(TFeatureHDDVDRead), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    with GET_CONFIGURATION_CDB
    do begin
      OperationCode         := SCSIOP_GET_CONFIGURATION;
      RequestType           := RT_Identified;
      StartingFeatureNumber := FEATURE_HDDVD_READ;
      AllocationLength      := SizeOf(TGET_CONFIGURATION_HDDVD_READ);
    end;
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, CDB10GENERIC_LENGTH);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigHDDVDRead, SizeOf(TGET_CONFIGURATION_HDDVD_READ));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigHDDVDRead,
                                    SizeOf(TGET_CONFIGURATION_HDDVD_READ))
    then begin
      DataLength := pConfigHDDVDRead.Header[0] shl 24 or
                    pConfigHDDVDRead.Header[1] shl 16 or
                    pConfigHDDVDRead.Header[2] shl  8 or
                    pConfigHDDVDRead.Header[3];
      {
      *  Wenn das HD DVD READ Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].HDDVDRead
      do begin
        FeatureCode := pConfigHDDVDRead.Data[0] shl 8 or pConfigHDDVDRead.Data[1];
        Version     := pConfigHDDVDRead.Data[2] and $3C shr 2;
        Persistent  := pConfigHDDVDRead.Data[2] and $02 > 0;
        Current     := pConfigHDDVDRead.Data[2] and $01 > 0;
        AddLength   := pConfigHDDVDRead.Data[3];
        {
        *  Wenn Daten existieren.
        }
        if AddLength > 0
        then begin
          R   := pConfigHDDVDRead.Data[4] and $01 > 0;
          RAM := pConfigHDDVDRead.Data[6] and $01 > 0;
        end;
        {
        *  Ergebnis
        }
        Result := FeatureCode = FEATURE_HDDVD_READ;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

HD DVD READ (podHDDVDRead.7z - 256 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.