Projekte > Optische Laufwerke > Merkmale

DVD+RW READ

GET CONFIGURATION Command - Operation Code $46
DVD+RW READ FEATURE - Feature Number $002A

Im Kapitel Feature wurde die Feature List ermittelt. Die Feature werden im Kapitel 5 beschrieben. In Kapitel 5.3.18 das DVD+RW READ FEATURE bekommt man Informationen zu DVD+RWs. Diese Eigenschaft ist nur vorhanden, wenn das Profile DVD-ROM ($0010) vorhanden ist.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $002A
3
4 Reserviert
5
6
7 Allocation Length = $10
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Die Nummer des gewünschten Feature. Das DVD+RW READ FEATURE hat die Featurenummer $002A.

Byte 7 und 8: Länge der Antwortstruktur. Sie muss so groß sein, dass die Antwort hineinpasst. Die Beschreibung des DVD+RW READ FEATURE ist acht Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 16.

Byte 9: Control - ?

 

Antwortstruktur

Die Struktur beginnt mit dem Feature Header:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

DVD+RW READ FEATURE Beschreibung:

  7 6 5 4 3 2 1 0
0 Feature Code = $002A
1
2 Reserviert Version = 0001b Persistent Current
3 Additional Length = $04
4 Reserved Write
5 Reserved Quick Start Close Only
6 Reserved
7

 

Feature Code - Muss der selbe wie im CDB sein. Hier war das DVD+RW READ Feature $002A ausgewählt.

Version - Die Versionsnummer muss 0001b sein.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss vier betragen.

Write - Gibt an, ob DVD+RW auch formatiert und beschrieben werden können.

Quick Start - Gibt an, ob der FORMAT UNIT command Quick Start Formatierung unterstützt.

Close Only - Wenn nicht gesetzt, werden beide background format stops unterstützt, sonst nur das read compatibility stop.

 

Deklaration

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_DVD_P_RW_READ = $002A;
 
  type
    TGET_CONFIGURATION_DVD_P_RW_READ = record
      Header : Array[0..7] of Byte;
      Data   : Array[0..7] of Byte;
    end;
    PGET_CONFIGURATION_DVD_P_RW_READ = ^TGET_CONFIGURATION_DVD_P_RW_READ;
 
  type
    TFeatureDVDpRWRead = record
      FeatureCode : Word;
      Version     : Byte;
      Persistent  : Boolean;
      Current     : Boolean;
      AddLength   : Byte;
      Write       : Boolean;
      QuickStart  : Boolean;
      CloseOnly   : Boolean;
    end;
          

 

Ausführung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  function TOptDrives.ReadConfigDVDpRWRead(aDevice: THandle): Boolean;
  {*******************************************************************************
  *  DVD+RW READ Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigDVDpRWRead     : PGET_CONFIGURATION_DVD_P_RW_READ;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  DVD+RW READ Feature initialisieren.
    }
    FillChar(FDrive[FActive].DVDpRWRead, SizeOf(TFeatureDVDpRWRead), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    with GET_CONFIGURATION_CDB
    do begin
      OperationCode         := SCSIOP_GET_CONFIGURATION;
      RequestType           := RT_Identified;
      StartingFeatureNumber := FEATURE_DVD_p_RW_READ;
      AllocationLength      := SizeOf(TGET_CONFIGURATION_DVD_P_RW_READ);
    end;
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigDVDpRWRead, SizeOf(TGET_CONFIGURATION_DVD_P_RW_READ));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigDVDpRWRead,
                                    SizeOf(TGET_CONFIGURATION_DVD_P_RW_READ))
    then begin
      DataLength := pConfigDVDpRWRead.Header[0] shl 24 or
                    pConfigDVDpRWRead.Header[1] shl 16 or
                    pConfigDVDpRWRead.Header[2] shl  8 or
                    pConfigDVDpRWRead.Header[3];
      {
      *  Wenn das DVD+RW READ Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].DVDpRWRead
      do begin
        FeatureCode := pConfigDVDpRWRead.Data[0] shl 8 or pConfigDVDpRWRead.Data[1];
        Version     := pConfigDVDpRWRead.Data[2] and $3C shr 2;
        Persistent  := pConfigDVDpRWRead.Data[2] and $02 > 0;
        Current     := pConfigDVDpRWRead.Data[2] and $01 > 0;
        AddLength   := pConfigDVDpRWRead.Data[3];
        {
        *  Wenn Daten existieren.
        }
        if AddLength > 0
        then begin
          Write      := pConfigDVDpRWRead.Data[4] and $01 > 0;
          QuickStart := pConfigDVDpRWRead.Data[5] and $02 > 0;
          CloseOnly  := pConfigDVDpRWRead.Data[5] and $01 > 0;
        end;
        {
        *  Ergebnis
        }
        Result := FDrive[FActive].DVDpRWRead.FeatureCode = FEATURE_DVD_P_RW_READ;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

DVD+RW READ (podDVDpRWRead.7z - 254 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.