Projekte > Optische Laufwerke > Merkmale

DVD READ

GET CONFIGURATION Command - Operation Code $46
DVD READ FEATURE - Feature Number $001F

Im Kapitel Feature wurde die Feature List ermittelt. Das DVD Read Feature ist in den Multimedia Commands 6 in Kapitel 5.3.9 beschrieben. Es gibt an, Doublelayermedien unterstützt werden.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code = $46
1 Reserviert RT = 10b
2 Starting Feature Number = $001F
3
4 Reserviert
5
6
7 Allocation Length = $10
8
9 Control

 

Werte

Byte 0 Operation Code - $46 GET CONFIGURATION Command

Byte 1 Request Type (RT) - 10b Feature Header, auch wenn das Feature nicht unterstützt wird.

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number $001F - Gibt an, dass die Eigenschaften des DVD READ FEATURE abgefragt werden sollen.

Byte 7 und 8: Länge der Antwortstruktur $10. - Die Beschreibung des DVD READ FEATURE ist acht Byte lang. Mit den acht Byte der Feature Beschreibung ergibt sich eine Länge von 16.

Byte 9: Control - ?

 

Antwortstruktur

Der Header ist wie auch bei den anderen Features:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 
Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Die DVD READ FEATURE Beschreibung nach Multimedia Commands 6:

  7 6 5 4 3 2 1 0
0 Feature Code = $001F
1
2 Reserviert Version = 0010b Persistent Current
3 Additional Length = $04
4 Reserved MULTI110
5 Reserved
6 Reserved Dual-RW Dual-R
7 Reserved

 
Feature Code - Muss der selbe wie im CDB sein. Hier war das DVD READ Feature $001F ausgewählt.

Version - Die Versionsnummer muss 0010b sein.

Persistent - Gibt an, ob der Status geändert werden kann oder ob das Feature ständig aktiv ist.

Current - Gibt an, ob das Feature gegenwärtig aktiv ist und featureabhängige Daten vorhanden sind.

Additional Length - Der Wert muss vier betragen.

MULTI110 - Gibt an, ob das Laufwerk Spezifizierungen für DVD Multi Drive Nurleselaufwerke (DVD Multi Specifications, Version 1.1) entspricht.

Dual-RW - Gibt ab, ob das Laufwerk DVD-RW DL lesen kann. Ist überholt und kann ignoriert werden.

Dual-R - Gibt ab, ob das Laufwerk DVD-R DL lesen kann.

 

Deklarationen

Zusätzlich zu den Deklarationen im Kapitel Feature werden diese vorgenommen:

 
  const
    FEATURE_DVD_READ = $001F;
 
  type
    TGET_CONFIGURATION_DVD_READ = record
      Header : array[0..7] of Byte;
      Data   : array[0..7] of Byte;
    end;
 
  type
    TFeatureDVDRead = record
      FeatureCode : Word;
      Version     : Byte;
      Persistent  : Boolean;
      Current     : Boolean;
      AddLength   : Byte;
      MULTI110    : Boolean;
      DualRW      : Boolean;
      DualR       : Boolean;
    end;
        

 

Ausführung

Nach der Aufruf des Commands wird die Antwortstruktur ausgewertet. Beispiel einer Funktion:

 
  function TOptDrives.ReadConfigDVDRead(aDevice: THandle): Boolean;
  {*******************************************************************************
  *  DVD Read Feature
  }
  var
    GET_CONFIGURATION_CDB : TGET_CONFIGURATION_CDB;
    pConfigDVDRead        : PGET_CONFIGURATION_DVD_READ;
    aCDB                  : Array of Byte;
    DataLength            : Cardinal;
  begin
    Result := False;
    {
    *  DVD READ Feature initialisieren.
    }
    FillChar(FDrive[FActive].DVDRead, SizeOf(TFeatureDVDRead), $00);
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
    GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
    GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_DVD_READ;
    GET_CONFIGURATION_CDB.AllocationLength    := SizeOf(TGET_CONFIGURATION_DVD_READ);
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
    {
    *  Befehl ausführen
    }
    GetMem(pConfigDVDRead, SizeOf(TGET_CONFIGURATION_DVD_READ));
    if GET_SCSI_PASS_THROUGH_DIRECT(aDevice, aCDB, pConfigDVDRead,
                                    SizeOf(TGET_CONFIGURATION_DVD_READ))
    then begin
      {
      *  Wenn der Abruf erfolgreich war...
      }
      DataLength := pConfigDVDRead.Header[0] shl 24 or
                    pConfigDVDRead.Header[1] shl 16 or
                    pConfigDVDRead.Header[2] shl  8 or
                    pConfigDVDRead.Header[3];
      {
      *  Wenn das DVD Read Feature existiert.
      }
      if DataLength > 4 then
      with FDrive[FActive].DVDRead
      do begin
        FeatureCode := pConfigDVDRead.Data[0] shl 8 or pConfigDVDRead.Data[1];
        Version     := pConfigDVDRead.Data[2] and $3C shr 2;
        Persistent  := pConfigDVDRead.Data[2] and $02 > 0;
        Current     := pConfigDVDRead.Data[2] and $01 > 0;
        AddLength   := pConfigDVDRead.Data[3];
        {
        *  Wenn Daten existieren.
        }
        if AddLength > 0
        then begin
          MULTI110 := pConfigDVDRead.Data[4] and $01 > 0;
          DualRW   := pConfigDVDRead.Data[6] and $02 > 0;
          DualR    := pConfigDVDRead.Data[6] and $01 > 0;
        end;
        {
        *  Ergebnis
        }
        Result := FDrive[FActive].DVDRead.FeatureCode = FEATURE_DVD_READ;
      end;
    end;
  end;
          

 

Demo, welche diese Funktion nutzt:

DVD Read (podDVDRead.7z - 252 kb) MD5 (1 kb). Stand: 2. Juni 2013

Änderungen an der Demo

Datum Beschreibung
02.06.2013Kleine Überarbeitung und neuer Name.