Avatar
www.fr-an.de

Hardwareinformationen

CD READ

GET CONFIGURATION Command - Operation Code $46
CD READ FEATURE - Feature Number $001E

Multi-Media Commands - 6: Mit dem GET CONFIGURATION Command (Kap. 6.5) werden Informationen über die Eigenschaften des Laufwerkes ermittelt. Die Eigenschaften können insgesamt oder einzeln abgerufen werden. Hier soll wiederum nur ein Feature, das CD READ Feature (Kap. 5.3.8), abgefragt werden.

Der GET CONFIGURATION Command Descriptor Block:

  7 6 5 4 3 2 1 0
0 Operation Code ($46)
1 Reserviert RT
2 Starting Feature Number
3
4 Reserviert
5
6
7 Allocation Length
8
9 Control

 

Die zu setzenden Werte:

Byte 0: Operation Code - $46

Byte 1: RT - Request Type - 01b:

Wert Beschreibung
00b Das Laufwerk soll den Feature Header und alle durch das Laufwerk unterstützten Feature Beschreibungen zurückgeben ohne Rücksicht auf Geltung.
01b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben.
10b Das Laufwerk soll den Feature Header und nur die gewählte Feature Beschreibung zurückgeben. Wird das Feature nicht unterstützt, soll nur der Feature Header zurückgegeben werden.
11b Reserviert

 
Byte 2 und 3: Starting Feature Number - Gibt die Nummer des auszugebenden Feature an. Das CD READ FEATURE hat die Featurenummer $001E.

Byte 7 und 8: Länge der Antwortstruktur. Die Länge muss so groß gewählt werden, dass die erwartete Antwort hineinpasst. Die Beschreibung des CD READ FEATURE ist acht Byte lang. Mit den acht Byte des FEATURE HEADER ergibt sich eine Länge von 16. Die Struktur sieht dann beginnend mit dem Feature Header so aus:

  7 6 5 4 3 2 1 0
0 Data Length
1
2
3
4 Reserviert
5
6 Current Profile
7

 
CD READ FEATURE Beschreibung:

  7 6 5 4 3 2 1 0
0 Feature Code = $001E
1
2 Reserviert Version = 0010b Persistent Current
3 Additional Length = $04
4 DAP Reserved C2 Flags CD-Text
5 Reserved
6
7

 
Byte 9: Control - ?

 

Deklaration und Vorbereitung

Die Werte werden ein- und übertragen. Das Beispiel ist vielleicht etwas umständlich, aber übersichtlicher und eben nur ein Beispiel:

 
  const
    SCSIOP_GET_CONFIGURATION = $46;
    FEATURE_CD_READ          = $001E;
    RT_All                   = 0;
    RT_Current               = 1;
    RT_Identified            = 2;
 
  type
    TGET_CONFIGURATION_CDB = record
      OperationCode         : Byte;
      RequestType           : Byte;
      StartingFeatureNumber : Word;
      AllocationLength      : Word;
    end;
 
  type
    TGET_CONFIGURATION_CD_READ = record
      Header : array[0..7] of Byte;
      Data   : array[0..7] of Byte;
    end;
 
    ...
 
  begin
 
    ...
 
    {
    *  Den Command Descriptor Block füllen.
    }
    ZeroMemory(@GET_CONFIGURATION_CDB, SizeOf(TGET_CONFIGURATION_CDB));
    GET_CONFIGURATION_CDB.OperationCode         := SCSIOP_GET_CONFIGURATION;
    GET_CONFIGURATION_CDB.RequestType           := RT_Identified;
    GET_CONFIGURATION_CDB.StartingFeatureNumber := FEATURE_CD_READ;
    GET_CONFIGURATION_CDB.AllocationLength      := SizeOf(TGET_CONFIGURATION_CD_READ);
    {
    *  Den Command Descriptor Block übertragen.
    }
    SetLength(aCDB, 10);
    aCDB[0] := GET_CONFIGURATION_CDB.OperationCode;
    aCDB[1] := GET_CONFIGURATION_CDB.RequestType;
    aCDB[2] := HiByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[3] := LoByte(GET_CONFIGURATION_CDB.StartingFeatureNumber);
    aCDB[7] := HiByte(GET_CONFIGURATION_CDB.AllocationLength);
    aCDB[8] := LoByte(GET_CONFIGURATION_CDB.AllocationLength);
 
    ...
 
  end;

 

Ausführung und Auswertung

Nach der Ausführung wird die Antwortstruktur ausgewertet.

 
  type
    TGetConfigurationHeader = record
      DataLength     : DWord;
      CurrentProfile : Word;
    end;
 
    TFeatureCDRead = record
      FeatureCode : Word;
      Version     : Byte;
      Persistent  : Boolean;
      Current     : Boolean;
      AddLength   : Byte;
      DAP         : Boolean;
      C2Flags     : Boolean;
      CDText      : Boolean;
    end;
 
    ...
 
  begin
 
    ...
 
    {
    *  Befehl ausführen
    }
    if GET_SCSI_PASS_THROUGH_DIRECT(aDrive, aCDB, @GET_CONFIGURATION_CD_READ,
                                    SizeOf(TGET_CONFIGURATION_CD_READ))
    then begin
      ConfigHeader.DataLength     := GET_CONFIGURATION_CD_READ.Header[0] shl 24 or
                                     GET_CONFIGURATION_CD_READ.Header[1] shl 16 or
                                     GET_CONFIGURATION_CD_READ.Header[2] shl  8 or
                                     GET_CONFIGURATION_CD_READ.Header[3];
      ConfigHeader.CurrentProfile := GET_CONFIGURATION_CD_READ.Header[6] shl 8 or
                                     GET_CONFIGURATION_CD_READ.Header[7];
      CDRead.FeatureCode := GET_CONFIGURATION_CD_READ.Data[0] shl 8 or
                            GET_CONFIGURATION_CD_READ.Data[1];
      CDRead.Version     := GET_CONFIGURATION_CD_READ.Data[2] and $3C shr 2;
      CDRead.Persistent  := GET_CONFIGURATION_CD_READ.Data[2] and $02 > 0;
      CDRead.Current     := GET_CONFIGURATION_CD_READ.Data[2] and $01 > 0;
      CDRead.AddLength   := GET_CONFIGURATION_CD_READ.Data[3];
      CDRead.DAP         := GET_CONFIGURATION_CD_READ.Data[4] and $80 > 0;
      CDRead.C2Flags     := GET_CONFIGURATION_CD_READ.Data[4] and $02 > 0;
      CDRead.CDText      := GET_CONFIGURATION_CD_READ.Data[4] and $01 > 0;
    end;
 
    ...
 
  end;

 

Die Rückgabewerte:

Data Length - Die Datenlänge im Header gibt die Länge des noch folgenden Headerrestes und der Feature Bechreibung an. Wird das Feature nicht unterstützt ist der Wert vier, sonst zwölf.

Current Profile - Gibt das aktive Profil an. Das Profil ist vom Laufwerk und dem eingelegten Datenträger abhängig. Sind mehrere Profile aktiv wird das Profil mit der höchsten Nummer angegeben. (Liste der Profile in einem Fenster öffnen.)

Feature Code - Muss der selbe wie im CDB sein. Hier war das CD READ Feature $001E ausgewählt.

Version - Die Versionsnummer muss 0010b sein.

Persistent - gibt an, ob sich der Wert ändern kann. Wenn das Flag gesetzt ist, ist die Eigenschaft immer aktiv und ändert sich nicht.

Current - gibt an, ob die Eigenschaft zur Zeit aktiv ist.

Additional Length - Der Wert muss vier betragen.

DAP - Gibt an, ob die READ CD und READ CD MSF Commands DAP unterstützen. Das Bit wird dort im CDB gesetzt.

C2 Flags - Gibt an, ob C2 Error Pointer unterstützt werden.

CD-Text - Gibt an, ob CD-Text unterstützt wird. Das heißt, es wird der Format Code $5 beim READ TOC/PMA/ATIP Command unterstützt.

 

Demo, welche diese Funktion nutzt:

Hardware CD READ (podHardCDRead.7z - 256 kb) MD5 (1 kb). Stand: 10. Januar 2012

 

Fr_An - Erstelt: 9. Janaur 2012 - Letzte Änderung: 21. Januar 2012

seit 28. Juli 2010